How to pass value from flash to php - php

Question

Hello i am new to the flash . Just i want to how to pass values from Flash variable to php
i am using this code
var myVars:LoadVars = new LoadVars();
myVars.playerName = "Some Body";
myVars.playerTime = Timer;
myVars.send("index.html", "_parent", "POST");`
it show error - >
Warning: 1060: Migration issue: The method LoadVars is no longer supported. For more information, see the URLVariables class, the URLRequest.urlVariables and URLRequest.postData properties, and the URLLoader.dataFormat property..
please guide me how do i resolve this error . i am using CS4 for flash and AS3.0

Answer 1

LoadVars() is AS2 only. You need to use URLLoader. Try this class:
package
{
import flash.net.URLRequest;
import flash.net.URLLoader;
import flash.net.URLVariables;
import flash.net.URLRequestMethod;
import flash.events.Event;
/**
* #author Marty Wallace
* #version 1.00
*/
public class PHPData extends Object
{
/**
* Sends data to a PHP script
* #param script A URL to the PHP script
*/
public function send(script:String, vars:URLVariables):void
{
var req:URLRequest = new URLRequest(script);
req.data = vars;
req.method = URLRequestMethod.POST;
var loader:URLLoader = new URLLoader();
loader.load(req);
// listeners
loader.addEventListener(Event.COMPLETE, _complete);
}
/**
* Called when a response has been received from a PHP script
* #param e Event.COMPLETE
*/
private function _complete(e:Event):void
{
var vars:URLVariables = new URLVariables(e.target.data);
var i:String;
for(i in vars)
{
trace(i + ": " + vars[i]);
}
e.target.removeEventListener(Event.COMPLETE, _complete);
}
}
}
Then you can do what you're doing like so:
var php:PHPData = new PHPData();
var vars:URLVariables = new URLVariables();
vars.playerName = "Some Body";
vars.playerTime = Timer;
php.send("index.php", vars);
Another thing I noticed was you're using send to send data to a .html document rather than a .php document..
A small tutorial on creating this class to use (based on comments):
Click File -> New -> ActionScript file.
Paste the above package (first chunk of code) into the new file.
Save the file in the same directory as your .fla file.
Paste my second snippet of code into the timeline of your .fla file.
All should work from here.
Here is a .zip containing an example you can use.
http://junk.projectavian.com?f=phpdata.zip